操作步驟

1. 創建專有網絡和交換機。本示例中在cn-hangzhou-b區域創建了一個專有網絡和交換機。

   1. 創建terraform.tf文件，輸入以下內容，并保存在當前的執行目錄中。

      variable "region" {
        default = "cn-hangzhou"
      }
      
      provider "alicloud" {
        region = var.region
      }
      
      data "alicloud_zones" "default" {
        available_resource_creation = "VSwitch"
      }
      
      resource "alicloud_vpc" "main" {
        vpc_name = "alicloud"
        # 專有網絡地址塊
        cidr_block = "10.1.0.0/21"
      }
      
      resource "alicloud_vswitch" "main" {
        vpc_id = alicloud_vpc.main.id
        # 交換機地址塊
        cidr_block = "10.1.0.0/24"
        # 可用區
        zone_id = data.alicloud_zones.default.zones[0].id
      }

   2. 運行terraform apply開始創建資源。

   3. 運行terraform show查看已創建的專有網絡和交換機。

2. 創建負載均衡實例，并添加監聽。本示例中創建了一個預付費的負載均衡實例，并添加了一個tcp監聽。

   1. 在terraform.tf文件中增加以下內容：

      resource "alicloud_slb_load_balancer" "instance" {
        load_balancer_name   = "slb_worder"
        load_balancer_spec   = "slb.s3.small"
        internet_charge_type = "PayByTraffic"
        address_type         = "intranet"
        vswitch_id           = alicloud_vswitch.main.id
      }
      
      resource "alicloud_slb_listener" "listener" {
        load_balancer_id = alicloud_slb_load_balancer.instance.id
        backend_port     = "2111"
        frontend_port    = "21"
        protocol         = "tcp"
        bandwidth        = "5"
      }

   2. 運行terraform apply開始創建。出現類似下面的日志，說明創建成功。

      alicloud_slb_load_balancer.instance: Creating...
      alicloud_slb_load_balancer.instance: Still creating... [10s elapsed]
      alicloud_slb_load_balancer.instance: Creation complete after 10s [id=lb-bp13b3e2m9l8wjwh3y8px]
      alicloud_slb_listener.listener: Creating...
      alicloud_slb_listener.listener: Creation complete after 3s [id=lb-bp13b3e2m9l8wjwh3y8px:tcp:21]
      ......
      Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

   3. 運行terraform show查看已經創建負載均衡實例。