完成以下操作，在Cloud Shell中使用Terraform：

1. 打開瀏覽器，訪問Cloud Shell的地址https://shell.aliyun.com。

   更多Cloud Shell入口及使用請參見使用云命令行。

2. 登錄Cloud Shell。

   說明

   建議您使用RAM賬號登錄，為確保您的阿里云賬號的安全，如非必要，避免使用阿里云賬號訪問云資源。

3. 編寫Terraform模板，命名為main.tf。

   您可以使用vim命令直接編寫模板，如果開通了OSS存儲，您可以直接將配置模板上傳到為Cloud Shell創建的bucket中。以下示例模板中的區域為北京，在運行之前您需要添加對應環境變量。

   示例：

   export ALICLOUD_REGION="cn-beijing" 

   provider "alicloud" {}
   
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "tf_test_foo"
     cidr_block = "172.16.0.0/12"
   }
   
   resource "alicloud_vswitch" "vsw" {
     vpc_id     = alicloud_vpc.vpc.id
     cidr_block = "172.16.0.0/21"
     zone_id    = "cn-beijing-b"
   }
   
   resource "alicloud_security_group" "default" {
     name   = "default"
     vpc_id = alicloud_vpc.vpc.id
   }
   
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.default.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   resource "alicloud_instance" "instance" {
     # 可用區
     availability_zone = "cn-beijing-b"
     # 綁定安全組
     security_groups = alicloud_security_group.default.*.id
   
     # 實例規格
     instance_type = "ecs.n2.small"
     # 系統盤類型
     system_disk_category = "cloud_efficiency"
     # 系統鏡像
     image_id = "ubuntu_18_04_64_20G_alibase_20190624.vhd"
     # 實例名稱
     instance_name = "test_foo"
     # 所在交換機
     vswitch_id = alicloud_vswitch.vsw.id
     # 公網帶寬
     internet_max_bandwidth_out = 10
   }

4. 執行terraform init命令初始化配置。

5. 執行terraform plan命令預覽配置。

6. 執行terraform apply創建ECS實例，如果執行結果返回Apply complete! ，則證明資源創建成功。

7. 若不再需要這臺實例，可執行terraform destroy對創建過的資源進行釋放。