操作步驟

1. 創建專有網絡和交換機。

   1. 創建terraform.tf文件，輸入以下內容，并保存在當前的執行目錄中。

      variable "region" {
        default = "cn-beijing"
      }
      
      variable "instance_type" {
        default = "ecs.n4.large"
      }
      
      provider "alicloud" {
        region = var.region
      }
      
      data "alicloud_zones" "default" {
        available_disk_category     = "cloud_efficiency"
        available_resource_creation = "VSwitch"
        available_instance_type     = var.instance_type
      }
      
      resource "alicloud_vpc" "vpc" {
        vpc_name   = "tf_test_foo"
        cidr_block = "172.16.0.0/12"
      }
      
      resource "alicloud_vswitch" "vsw" {
        vpc_id     = alicloud_vpc.vpc.id
        cidr_block = "172.16.0.0/21"
        zone_id    = data.alicloud_zones.default.zones.0.id
      }

   2. 運行terraform init進行初始化。

   3. 運行terraform apply開始創建。

   4. 運行terraform show查看已創建的專有網絡和交換機。

      您也可以登錄VPC控制臺查看專有網絡和交換機的屬性。

2. 在上一步創建的專有網絡中創建一個安全組，并添加一個允許任何地址訪問的安全組規則。

   1. 在terraform.tf文件中增加以下內容。

      resource "alicloud_security_group" "default" {
        name   = "default"
        vpc_id = alicloud_vpc.vpc.id
      }
      
      resource "alicloud_security_group_rule" "allow_all_tcp" {
        type              = "ingress"
        ip_protocol       = "tcp"
        nic_type          = "intranet"
        policy            = "accept"
        port_range        = "1/65535"
        priority          = 1
        security_group_id = alicloud_security_group.default.id
        cidr_ip           = "0.0.0.0/0"
      }

   2. 運行terraform apply開始創建。

   3. 運行terraform show查看已創建的安全組和安全組規則。

      您也可以登錄ECS控制臺查看安全組和安全組規則。

3. 創建ECS實例。

   1. 在terraform.tf文件中增加以下內容。

      resource "alicloud_instance" "instance" {
        # cn-beijing
        availability_zone = data.alicloud_zones.default.zones.0.id
        security_groups   = alicloud_security_group.default.*.id
        # series III
        instance_type              = var.instance_type
        system_disk_category       = "cloud_efficiency"
        image_id                   = var.image_id
        instance_name              = "test_foo"
        vswitch_id                 = alicloud_vswitch.vsw.id
        internet_max_bandwidth_out = 10
      }
      
      output "public_ip" {
          value = alicloud_instance.instance.public_ip
      }

      說明

      • 在上述示例中，指定了internet_max_bandwidth_out= 10，因此會自動為實例分配一個公網IP，輸出到 output 中。

      • 詳細的參數解釋請參見 阿里云參數說明。

   2. 運行terraform apply開始創建。

   3. 運行terraform show查看已創建的ECS實例。

   4. 運行ssh root@<publicip>，并輸入設定好的密碼來訪問ECS實例。