前提條件

• 完成此教程，您需要開通以下服務：

  • 企業級分布式應用服務EDAS：如果需要開通此服務，請參見開通EDAS。

  • 負載均衡：請參見CLB計費概述。

  • 云服務器ECS：請參見計費概述。

• 為了降低信息安全風險，建議使用最小權限的RAM用戶完成此教程的操作。請參見創建RAM用戶與為RAM用戶授權，完成此教程所需最小權限的權限策略如下：

  {
    "Version": "1",
    "Statement": [
      {
        "Effect": "Allow",
        "Action": [
          "edas:CreateCluster",
          "edas:ReadCluster",
          "edas:DeleteCluster",
          "edas:ListResourceGroup",
          "edas:ListServiceGroups",
          "edas:ListSwimmingLaneGroup",
          "edas:ReadApplication",
          "edas:ListSlb",
          "edas:DeleteApplication"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": [
          "ecs:CreateSecurityGroup",
          "ecs:ModifySecurityGroupPolicy",
          "ecs:DescribeSecurityGroups",
          "ecs:ListTagResources",
          "ecs:DeleteSecurityGroup",
          "ecs:DescribeSecurityGroupAttribute",
          "ecs:RunInstances",
          "ecs:DescribeInstances",
          "ecs:DescribeUserData",
          "ecs:DescribeInstanceRamRole",
          "ecs:DescribeInstanceAttribute",
          "ecs:DescribeNetworkInterfaces",
          "ecs:DescribeInstanceMaintenanceAttributes",
          "ecs:DescribeDisks",
          "ecs:DeleteInstance"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": [
          "edas:ManageCluster",
          "edas:SynchronizeResource",
          "edas:CreateApplication",
          "edas:ManageApplication",
          "edas:QueryMigrateEcuList",
          "edas:ReadApplication"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": [
          "slb:CreateLoadBalancer",
          "slb:DescribeLoadBalancerAttribute",
          "slb:ListTagResources",
          "slb:DeleteLoadBalancer"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": [
          "vpc:CreateVpc",
          "vpc:DeleteVpc",
          "vpc:CreateVSwitch",
          "vpc:DeleteVSwitch"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": [
          "vpc:DescribeVpcAttribute",
          "vpc:DescribeRouteTableList",
          "vpc:DescribeVSwitchAttributes"
        ],
        "Resource": "*"
      },
      {
        "Effect": "Allow",
        "Action": "kms:CreateKey",
        "Resource": "*"
      }
    ]
  }

• 準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。

  • Explorer：阿里云提供了Terraform的在線運行環境，您無需安裝Terraform，登錄后即可在線使用和體驗Terraform。適用于零成本、快速、便捷地體驗和調試Terraform的場景。

  • Cloud Shell：阿里云Cloud Shell中預裝了Terraform的組件，并已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用于低成本、快速、便捷地訪問和使用Terraform的場景。

  • 在本地安裝和配置Terraform：適用于網絡連接較差或需要自定義開發環境的場景。

使用的資源

• alicloud_vpc：專有網絡VPC。

• alicloud_security_group：安全組。

• alicloud_vswitch：交換機。

• alicloud_instance：ECS實例。

• alicloud_edas_cluster：阿里云ECS集群。

• alicloud_edas_instance_cluster_attachment：ECS集群添加實例。

• alicloud_edas_application：EDAS ECS應用。

• alicloud_edas_deploy_group：應用分組。

• alicloud_edas_application_scale：應用擴容。

• alicloud_edas_application_deployment：應用部署。

• alicloud_slb_load_balancer：負載均衡實例。

• alicloud_edas_slb_attachment：應用綁定負載均衡。

步驟一：創建ECS

1. 創建一個工作目錄，并在該工作目錄中創建名為main.tf的配置文件。以下代碼將創建一個ECS實例，以及創建ECS實例所需的VPC、安全組與交換機資源。將以下代碼復制到main.tf中。

   variable "region" {
     default = "cn-shanghai"
   }
   
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # 官網demo地址
   variable "war_url" {
     type    = string
     default = "http://edas-sz.oss-cn-shenzhen.aliyuncs.com/prod/demo/SPRING_CLOUD_CONSUMER.jar"
   }
   
   provider "alicloud" {
     region = var.region
   }
   
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # 隨機數
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 創建專有網絡VPC
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # 創建安全組
   resource "alicloud_security_group" "group" {
     name   = "test_${random_integer.default.result}"
     vpc_id = alicloud_vpc.vpc.id
   }
   
   # 創建交換機
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # 創建ECS
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = alicloud_security_group.group.*.id
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example"
   }
   
   # 創建ecs實例成功之后等待實例初始化完成，一般不超過60s
   resource "time_sleep" "example" {
     depends_on      = [alicloud_instance.instance]
     create_duration = "60s"
   }

2. 執行如下命令，初始化Terraform運行環境。

   terraform init

   返回信息如下，則Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示代碼執行成功。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. 驗證結果。

   執行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創建資源的詳細信息：

   terraform show

   

   登錄控制臺查看

   登錄云服務器管理控制臺 (aliyun.com)，進入實例與鏡像 > 實例頁面，左上角選擇地區，此例中選擇華東2（上海），查看已創建的ECS實例。

   

步驟二：創建ECS集群并添加ECS

1. 在main.tf文件中增加如下代碼。

   # 創建ECS集群
   resource "alicloud_edas_cluster" "cluster" {
     cluster_name      = "tf-edas-${random_integer.default.result}"
     cluster_type      = "2"
     network_mode      = "2"
     logical_region_id = var.region
     vpc_id            = alicloud_vpc.vpc.id
   }
   
   # 添加ECS實例到ECS集群
   resource "alicloud_edas_instance_cluster_attachment" "default" {
     depends_on   = [time_sleep.example]
     cluster_id   = alicloud_edas_cluster.cluster.id
     instance_ids = [alicloud_instance.instance.id]
   }

2. 創建執行計劃，并預覽變更。

   terraform plan

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示代碼執行成功。

   Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

4. 驗證結果。

   執行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創建資源的詳細信息：

   terraform show

   

   登錄控制臺查看

   1. 登錄企業級分布式應用服務（EDAS） (aliyun.com)，進入資源管理 > EDAS ECS 集群頁面，左上角選擇地區，此例中選擇華東2 （上海），查看已創建的ECS集群。

      

   2. 單擊此此教程創建的ECS集群ID，查看集群詳情。

      

步驟三：創建應用與應用分組

1. 在main.tf文件中增加如下代碼。

   # 創建應用
   resource "alicloud_edas_application" "app" {
     application_name = "tf-test-app-${random_integer.default.result}"
     cluster_id       = alicloud_edas_cluster.cluster.id
     package_type     = "JAR"
   }
   
   # 創建應用分組
   resource "alicloud_edas_deploy_group" "this" {
     app_id     = alicloud_edas_application.app.id
     group_name = "tf-test-group-${random_integer.default.result}"
   }

2. 創建執行計劃，并預覽變更。

   terraform plan

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示代碼執行成功。

   Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

4. 驗證結果。

   執行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創建資源的詳細信息：

   terraform show

   

   登錄控制臺查看

   1. 登錄企業級分布式應用服務（EDAS） (aliyun.com)，進入應用管理 > 應用列表頁面，左上角選擇地區，此例中選擇華東2 （上海），查看已創建的應用。

      

   2. 單擊此例創建應用的應用名稱，進入實例部署信息頁簽，查看應用的分組信息。

      

步驟四：應用擴容并部署

1. 在main.tf文件中增加如下代碼。

   # 截取應用分組ID
   locals {
     parts    = split(":", alicloud_edas_deploy_group.this.id)
     group_id = local.parts[2]
   }
   
   # 應用擴容
   resource "alicloud_edas_application_scale" "default" {
     app_id       = alicloud_edas_application.app.id
     deploy_group = local.group_id
     ecu_info     = [alicloud_edas_instance_cluster_attachment.default.ecu_map[alicloud_instance.instance.id]]
   }
   
   # 部署應用
   resource "alicloud_edas_application_deployment" "default" {
     depends_on = [alicloud_edas_application_scale.default, alicloud_edas_instance_cluster_attachment.default]
     app_id     = alicloud_edas_application.app.id
     group_id   = local.group_id
     war_url    = var.war_url
   }
   
   # 部署應用成功后等待應用啟動，一般不超過60s
   resource "time_sleep" "example2" {
     depends_on      = [alicloud_edas_application_deployment.default]
     create_duration = "60s"
   }

2. 創建執行計劃，并預覽變更。

   terraform plan

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示代碼執行成功。

   Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

4. 驗證結果。

   執行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創建資源的詳細信息：

   terraform show

   

   登錄控制臺查看

   登錄企業級分布式應用服務（EDAS） (aliyun.com)，進入應用管理 > 應用列表頁面，左上角選擇地區，此例中選擇華東2 （上海），查看已創建的應用。單擊此例創建應用的應用名稱，進入實例部署信息頁簽，查看應用的部署信息。

   

步驟五：創建SLB并綁定應用

1. 在main.tf文件中增加如下代碼。

   # 創建SLB
   resource "alicloud_slb_load_balancer" "default" {
     load_balancer_name = "tf-test-slb-${random_integer.default.result}"
     vswitch_id         = alicloud_vswitch.vswitch.id
     load_balancer_spec = "slb.s2.small"
     address_type       = "intranet"
   }
   
   # 綁定SLB
   resource "alicloud_edas_slb_attachment" "this" {
     depends_on = [time_sleep.example2]
     app_id     = alicloud_edas_application.app.id
     slb_id     = alicloud_slb_load_balancer.default.id
     slb_ip     = alicloud_slb_load_balancer.default.address
     type       = alicloud_slb_load_balancer.default.address_type
   }

2. 創建執行計劃，并預覽變更。

   terraform plan

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示代碼執行成功。

   Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

4. 驗證結果。

   執行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創建資源的詳細信息：

   terraform show

   

   登錄控制臺查看

   登錄企業級分布式應用服務（EDAS） (aliyun.com)，進入應用管理 > 應用列表頁面，左上角選擇地區，此例中選擇華東2 （上海），查看已創建的應用。單擊此例創建應用的應用名稱，進入基本信息頁簽，查看應用的基本信息。

   

清理資源

當您不再需要上述通過Terraform創建或管理的資源時，請運行以下命令以釋放資源。關于terraform destroy的更多信息，請參見Terraform常用命令。

terraform destroy

完整示例

variable "region" {
  default = "cn-shanghai"
}

variable "instance_type" {
  type    = string
  default = "ecs.e-c1m1.large"
}

variable "vpc_cidr_block" {
  default = "172.16.0.0/16"
}

variable "vsw_cidr_block" {
  default = "172.16.0.0/24"
}

# 官網demo地址
variable "war_url" {
  type    = string
  default = "http://edas-sz.oss-cn-shenzhen.aliyuncs.com/prod/demo/SPRING_CLOUD_CONSUMER.jar"
}

provider "alicloud" {
  region = var.region
}

# 截取應用分組ID
locals {
  parts    = split(":", alicloud_edas_deploy_group.this.id)
  group_id = local.parts[2]
}

data "alicloud_zones" "default" {
  available_instance_type     = var.instance_type
  available_resource_creation = "VSwitch"
  available_disk_category     = "cloud_essd"
}

# 隨機數
resource "random_integer" "default" {
  min = 10000
  max = 99999
}

# 創建專有網絡VPC
resource "alicloud_vpc" "vpc" {
  vpc_name   = "vpc-test_${random_integer.default.result}"
  cidr_block = var.vpc_cidr_block
}

# 創建安全組
resource "alicloud_security_group" "group" {
  name   = "test_${random_integer.default.result}"
  vpc_id = alicloud_vpc.vpc.id
}

# 創建交換機
resource "alicloud_vswitch" "vswitch" {
  vpc_id       = alicloud_vpc.vpc.id
  cidr_block   = var.vsw_cidr_block
  zone_id      = data.alicloud_zones.default.zones[0].id
  vswitch_name = "vswitch-test-${random_integer.default.result}"
}

# 創建ECS
resource "alicloud_instance" "instance" {
  availability_zone          = data.alicloud_zones.default.zones[0].id
  security_groups            = alicloud_security_group.group.*.id
  instance_type              = var.instance_type
  system_disk_category       = "cloud_essd"
  system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
  system_disk_description    = "test_foo_system_disk_description"
  image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
  instance_name              = "test_ecs_${random_integer.default.result}"
  vswitch_id                 = alicloud_vswitch.vswitch.id
  internet_max_bandwidth_out = 10
  password                   = "Terraform@Example"
}

# 創建ecs實例成功之后等待實例初始化完成，一般不超過60s
resource "time_sleep" "example" {
  depends_on      = [alicloud_instance.instance]
  create_duration = "60s"
}

# 創建ECS集群
resource "alicloud_edas_cluster" "cluster" {
  cluster_name      = "tf-edas-${random_integer.default.result}"
  cluster_type      = "2"
  network_mode      = "2"
  logical_region_id = var.region
  vpc_id            = alicloud_vpc.vpc.id
}

# 添加ECS實例到ECS集群
resource "alicloud_edas_instance_cluster_attachment" "default" {
  depends_on   = [time_sleep.example]
  cluster_id   = alicloud_edas_cluster.cluster.id
  instance_ids = [alicloud_instance.instance.id]
}

# 創建應用
resource "alicloud_edas_application" "app" {
  application_name = "tf-test-app-${random_integer.default.result}"
  cluster_id       = alicloud_edas_cluster.cluster.id
  package_type     = "JAR"
}

# 創建應用分組
resource "alicloud_edas_deploy_group" "this" {
  app_id     = alicloud_edas_application.app.id
  group_name = "tf-test-group-${random_integer.default.result}"
}

# 應用擴容
resource "alicloud_edas_application_scale" "default" {
  app_id       = alicloud_edas_application.app.id
  deploy_group = local.group_id
  ecu_info     = [alicloud_edas_instance_cluster_attachment.default.ecu_map[alicloud_instance.instance.id]]
}

# 部署應用
resource "alicloud_edas_application_deployment" "default" {
  depends_on = [alicloud_edas_application_scale.default, alicloud_edas_instance_cluster_attachment.default]
  app_id     = alicloud_edas_application.app.id
  group_id   = local.group_id
  war_url    = var.war_url
}

# 部署應用成功后等待應用啟動，一般不超過60s
resource "time_sleep" "example2" {
  depends_on      = [alicloud_edas_application_deployment.default]
  create_duration = "60s"
}

# 創建SLB
resource "alicloud_slb_load_balancer" "default" {
  load_balancer_name = "tf-test-slb-${random_integer.default.result}"
  vswitch_id         = alicloud_vswitch.vswitch.id
  load_balancer_spec = "slb.s2.small"
  address_type       = "intranet"
}

# 綁定SLB
resource "alicloud_edas_slb_attachment" "this" {
  depends_on = [time_sleep.example2]
  app_id     = alicloud_edas_application.app.id
  slb_id     = alicloud_slb_load_balancer.default.id
  slb_ip     = alicloud_slb_load_balancer.default.address
  type       = alicloud_slb_load_balancer.default.address_type
}

如果您想體驗更多完整示例，請前往更多完整示例中對應產品的文件夾查看。

相關文檔

• Terrafrom介紹，請參見Terraform產品介紹。

• 當您遇到由于網絡延遲等原因造成的 terraform init 超時，導致無法正常下載 Provider 等情況時，請參見Terraform Init 加速方案配置。

• 如果您不了解教程中使用的SLB，請參見什么是傳統型負載均衡CLB。