前提條件

• 建議使用RAM用戶完成此教程的操作，并授予AliyunCloudSSOFullAccess權(quán)限，創(chuàng)建RAM用戶請(qǐng)參見創(chuàng)建RAM用戶，授權(quán)請(qǐng)參見為RAM用戶授權(quán)。

• 準(zhǔn)備Terraform運(yùn)行環(huán)境，您可以選擇以下任一方式來使用Terraform。

  • Explorer：阿里云提供了Terraform的在線運(yùn)行環(huán)境，您無需安裝Terraform，登錄后即可在線使用和體驗(yàn)Terraform。適用于零成本、快速、便捷地體驗(yàn)和調(diào)試Terraform的場(chǎng)景。

  • Cloud Shell：阿里云Cloud Shell中預(yù)裝了Terraform的組件，并已配置好身份憑證，您可直接在Cloud Shell中運(yùn)行Terraform的命令。適用于低成本、快速、便捷地訪問和使用Terraform的場(chǎng)景。

  • 在本地安裝和配置Terraform：適用于網(wǎng)絡(luò)連接較差或需要自定義開發(fā)環(huán)境的場(chǎng)景。

使用的資源

• alicloud_cloud_sso_directory：云SSO目錄。

• alicloud_cloud_sso_user：云SSO用戶。

創(chuàng)建云SSO用戶

1. 創(chuàng)建一個(gè)文件夾作為Terraform工作目錄，并在該工作目錄中創(chuàng)建名為main.tf的配置文件，然后將以下代碼復(fù)制到main.tf中。

   variable "region" {
     default = "cn-shanghai"
   }
   
   provider "alicloud" {
     region = var.region
   }
   
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 獲取云SSO目錄
   data "alicloud_cloud_sso_directories" "default" {}
   
   # 創(chuàng)建目錄，一個(gè)賬號(hào)只能創(chuàng)建一個(gè)目錄
   resource "alicloud_cloud_sso_directory" "default" {
     directory_name = "sso-directory-${random_integer.default.result}"
     # 如果已有目錄，則不新建目錄；如果沒有目錄，則新建一個(gè)目錄
     count          = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? 0 : 1
   }
   
   # directory_id 的值為全局唯一目錄的id
   locals {
     directory_id = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? data.alicloud_cloud_sso_directories.default.ids[0] : concat(alicloud_cloud_sso_directory.default.*.id, [""])[0]
   }
   
   # 創(chuàng)建云SSO用戶
   resource "alicloud_cloud_sso_user" "default" {
     user_name    = "sso-user-${random_integer.default.result}"
     directory_id = local.directory_id
   }

2. 執(zhí)行如下命令，初始化Terraform運(yùn)行環(huán)境。

   terraform init

   返回信息如下，則Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 執(zhí)行如下命令，開始執(zhí)行代碼。

   terraform apply

   在執(zhí)行過程中，根據(jù)提示輸入yes并按下Enter鍵，等待命令執(zhí)行完成，若出現(xiàn)以下信息，則表示代碼執(zhí)行成功。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

4. 驗(yàn)證結(jié)果。

   執(zhí)行terraform show命令

   您可以在工作目錄中，使用以下命令查詢Terraform已創(chuàng)建資源的詳細(xì)信息：

   terraform show

   

   登錄控制臺(tái)查看

   登錄云SSO控制臺(tái)，查看已創(chuàng)建的用戶。

   

清理資源

當(dāng)您不再需要上述通過Terraform創(chuàng)建或管理的資源時(shí)，請(qǐng)運(yùn)行以下命令釋放資源。關(guān)于terraform destroy的更多信息，請(qǐng)參見Terraform常用命令。

terraform destroy

完整示例

variable "region" {
  default = "cn-shanghai"
}

provider "alicloud" {
  region = var.region
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

# 獲取云SSO目錄
data "alicloud_cloud_sso_directories" "default" {}

# 創(chuàng)建目錄
resource "alicloud_cloud_sso_directory" "default" {
  directory_name = "sso-directory-${random_integer.default.result}"
  # 如果已有目錄，則不新建目錄；如果沒有目錄，則新建一個(gè)目錄
  count          = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? 0 : 1
}

# directory_id 的值為全局唯一目錄的id
locals {
  directory_id = length(data.alicloud_cloud_sso_directories.default.ids) > 0 ? data.alicloud_cloud_sso_directories.default.ids[0] : concat(alicloud_cloud_sso_directory.default.*.id, [""])[0]
}

# 創(chuàng)建云SSO用戶
resource "alicloud_cloud_sso_user" "default" {
  user_name    = "sso-user-${random_integer.default.result}"
  directory_id = local.directory_id
}

如果您想體驗(yàn)更多完整示例，請(qǐng)前往更多完整示例中對(duì)應(yīng)產(chǎn)品的文件夾查看。

相關(guān)文檔

• Terrafrom介紹，請(qǐng)參見Terraform產(chǎn)品介紹。

• 當(dāng)您遇到由于網(wǎng)絡(luò)延遲等原因造成的terraform init超時(shí)，導(dǎo)致無法正常下載Provider等情況時(shí)，請(qǐng)參見Terraform Init 加速方案配置。