使用的資源

使用Terraform創建彈性伸縮資源

本示例將創建伸縮組、伸縮配置和伸縮規則等彈性伸縮資源

1. 創建一個工作目錄，并在該工作目錄中創建名為main.tf的配置文件，然后將以下代碼復制到main.tf中。

   variable "region" {
     default = "cn-heyuan"
   }
   
   variable "instance_type" {
     default = "ecs.hfc7.xlarge"
   }
   
   variable "image_id" {
     default = "aliyun_2_1903_x64_20G_alibase_20210120.vhd"
   }
   
   variable "zone_id" {
     default = "cn-heyuan-b"
   }
   
   provider "alicloud" {
     region = var.region
   }
   
   #創建專有網絡VPC。
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "tf-test-vpc-wjt"
     cidr_block = "172.16.0.0/12" #規劃專有網絡VPC的私網網段。
   }
   
   #創建專有網絡交換機。
   resource "alicloud_vswitch" "vsw" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = "172.16.0.0/21" #規劃交換機的私網網段。
     zone_id      = var.zone_id     #選擇交換機的可用區。
     vswitch_name = "tf-test-vswitch-wjt"
   }
   
   #創建一個安全組。
   resource "alicloud_security_group" "security" {
     name        = "tf_test_security"
     description = "New security group"
     vpc_id      = alicloud_vpc.vpc.id
   }
   
   #并為該安全組添加一個允許任何地址訪問的安全組規則。
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.security.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   #本示例以創建最大實例數為100的伸縮組為例。
   resource "alicloud_ess_scaling_group" "group" {
     scaling_group_name = "tf_test_scalinggroup"
     min_size           = 0
     max_size           = 100
     vswitch_ids        = [alicloud_vswitch.vsw.id]
   }
   
   #本示例以創建ECS類型的伸縮配置為例。
   resource "alicloud_ess_scaling_configuration" "configuration" {
     scaling_group_id           = alicloud_ess_scaling_group.group.id
     instance_type              = var.instance_type
     image_id                   = var.image_id
     security_group_id          = alicloud_security_group.security.id
     scaling_configuration_name = "tf_test_scalingconfiguration"
     system_disk_category       = "cloud_essd"
     spot_strategy              = "SpotWithPriceLimit"
     active                     = true
     force_delete               = true
   }
   
   #創建伸縮規則
   resource "alicloud_ess_scaling_rule" "rule" {
     scaling_group_id = alicloud_ess_scaling_group.group.id
     adjustment_type  = "QuantityChangeInCapacity"
     adjustment_value = 1
   }

2. 執行以下命令，初始化Terraform運行環境。

   terraform init

   返回如下信息，表示Terraform初始化成功。

   Initializing the backend...
   
   Initializing provider plugins...
   - Checking for available provider plugins...
   - Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
   ...
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 創建執行計劃，并預覽變更。

   terraform plan

4. 執行以下命令，創建資源。

   terraform apply

   在執行過程中，根據提示輸入yes并按下Enter鍵，等待命令執行完成，若出現以下信息，則表示彈性伸縮資源創建成功。

   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   ...
   alicloud_security_group_rule.allow_all_tcp: Creation complete after 0s [id=sg-f8z1mes******:ingress:tcp:1/65535:intranet:0.0.0.0/0:accept:1]
   alicloud_vswitch.vsw: Creation complete after 3s [id=vsw-f8ztgc4******]
   alicloud_ess_scaling_group.group: Creating...
   alicloud_ess_scaling_group.group: Creation complete after 2s [id=asg-f8z9mo******]
   ...
   
   Apply complete! Resources: 7 added, 0 changed, 0 destroyed.

5. 驗證結果

   執行terraform show命令

   您可以使用以下命令查詢Terraform已創建的資源詳細信息：

   terraform show

   

   登錄彈性伸縮管理控制臺

   登錄彈性伸縮管理控制臺，查看已創建的彈性伸縮組。

   

清理資源

當您不再需要上述通過Terraform創建或管理的資源時，請運行以下命令以釋放資源。關于terraform destroy的更多信息，請參見Terraform常用命令。

terraform destroy

variable "region" {
  default = "cn-heyuan"
}

variable "instance_type" {
  default = "ecs.hfc7.xlarge"
}

variable "image_id" {
  default = "aliyun_2_1903_x64_20G_alibase_20210120.vhd"
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

provider "alicloud" {
  region = var.region
}

#創建專有網絡VPC。
resource "alicloud_vpc" "vpc" {
  vpc_name   = "tf-test-vpc-wjt"
  cidr_block = "172.16.0.0/12" #規劃專有網絡VPC的私網網段。
}

#創建專有網絡交換機。
resource "alicloud_vswitch" "vsw" {
  vpc_id       = alicloud_vpc.vpc.id
  cidr_block   = "172.16.0.0/21" #規劃交換機的私網網段。
  zone_id      = var.zone_id     #選擇交換機的可用區。
  vswitch_name = "tf-test-vswitch-wjt"
}

#創建一個安全組。
resource "alicloud_security_group" "security" {
  name        = "tf_test_security"
  description = "New security group"
  vpc_id      = alicloud_vpc.vpc.id
}

#并為該安全組添加一個允許任何地址訪問的安全組規則。
resource "alicloud_security_group_rule" "allow_all_tcp" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "1/65535"
  priority          = 1
  security_group_id = alicloud_security_group.security.id
  cidr_ip           = "0.0.0.0/0"
}

#本示例以創建最大實例數為100的伸縮組為例。
resource "alicloud_ess_scaling_group" "group" {
  scaling_group_name = "tf_test_scalinggroup"
  min_size           = 0
  max_size           = 100
  vswitch_ids        = [alicloud_vswitch.vsw.id]
}

#本示例以創建ECS類型的伸縮配置為例。
resource "alicloud_ess_scaling_configuration" "configuration" {
  scaling_group_id           = alicloud_ess_scaling_group.group.id
  instance_type              = var.instance_type
  image_id                   = var.image_id
  security_group_id          = alicloud_security_group.security.id
  scaling_configuration_name = "tf_test_scalingconfiguration"
  system_disk_category       = "cloud_essd"
  spot_strategy              = "SpotWithPriceLimit"
  active                     = true
  force_delete               = true
}

#創建伸縮規則
resource "alicloud_ess_scaling_rule" "rule" {
  scaling_group_id = alicloud_ess_scaling_group.group.id
  adjustment_type  = "QuantityChangeInCapacity"
  adjustment_value = 1
}