組件類型

容器服務ACK管理的集群組件類型包括系統組件和可選組件。更多組件信息，請參見組件概述。

系統組件

可選組件

可選組件是ACK提供的非必需部署的組件，您可選擇性的安裝組件，用于擴展集群功能。可選組件在類型上可劃分為應用管理組件、日志與監控管理組件、存儲組件、網絡組件及安全組件等。

組件管理實踐

通過Terraform，您可以在創建集群時指定需要安裝的組件，并在集群創建結束后對組件進行全生命周期管理，下面將介紹如何管理集群中的組件生命周期，以及一些場景下的最佳實踐。

在創建集群時指定需要安裝的組件

您可以在創建集群時，指定集群需要安裝的組件，創建集群涉及的Resource如下：

• Kubernetes托管版集群：alicloud_cs_managed_kubernetes

• Kubernetes專有版集群：alicloud_cs_kubernetes

• ACK Edge集群：alicloud_cs_edge_kubernetes

• ACK Serverless集群：alicloud_cs_serverless_kubernetes

以上Resource均可以通過addons屬性定義創建集群時需要安裝的組件，addons屬性定義如下：

# 以托管版集群為例。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  # addons為list結構，通過在Resource中定義addons屬性，表明創建集群時安裝該組件。
  addons {
    # 組件的名稱，您可以通過Data Source中的alicloud_cs_kubernetes_addons查詢。
    # 當前集群已經安裝的，以及可以安裝的組件和其對應版本信息。
    name = "XXX"

    # 組件的自定義參數，某些集群組件開啟了自定義參數配置的能力，您可以使用該字段來為組件指定其自定義參數，具體指定方法，請參見下文“修改集群組件的自定義配置參數”一節。
    config = jsonencode(
      {
        ....
      }
    )

    # 該參數默認值為false（布爾值類型），ACK會默認安裝部分組件，方便用戶管理集群。若您在創建集群時不需安裝這些組件，可設置disabled=true。
    disabled = XXX
  }
}

ACK中組件配置方式如下表所示。

在創建集群后管理組件生命周期

管理組件的生命周期前提是您已經創建了一個Kubernetes集群，如果您還沒有創建Kubernetes集群，請先創建集群。

對于集群中的組件，您可以通過Resource中的alicloud_cs_kubernetes_addon來管理組件的生命周期，包括組件的安裝、升級、卸載、自定義配置的修改。alicloud_cs_kubernetes_addon的屬性和定義如下：

resource "alicloud_cs_kubernetes_addon" "addon-example" {
  # 集群ID。
  cluster_id = "XXXX"

  # 組件的名稱，可以通過Data Source中的alicloud_cs_kubernetes_addons，查詢當前集群所有已安裝的以及可以安裝的組件和其對應版本信息。
  name = "XXXX"

  # 組件的版本信息。
  version = "XXXX"

  # 組件的自定義參數，為JSON格式的字符串，可以使用Terraform自帶的jsonencode方法進行配置，也可以直接使用JSON字符串進行配置（需要注意轉義），某些集群組件開啟了自定義參數配置的能力，您可以使用該字段來為組件指定其自定義參數，具體指定方法，請參見下文“修改集群組件的自定義配置參數”一節 。
  config = jsonencode(
    {
      ....
    }
  )
}

您可以通過直接寫入JSON字符串的方式配置組件自定義參數，但是需要注意轉義。例如對于nginx-ingress-controller組件，有以下兩種配置方法：

• 通過jsonencode配置參數：

  config = jsonencode(   
    {       
      IngressSlbNetworkType="internet"       
      IngressSlbSpec="slb.s2.small"     
    }  
  )

• 通過直接使用字符串的方式配置參數：

  config = "{\"IngressSlbNetworkType\":\"internet\",\"IngressSlbSpec\":\"slb.s2.small\"}"

將集群已安裝的組件導入Terraform管理

對于集群已經安裝的組件，您可以通過terraform import的方式，將組件導入Terraform進行管理。下面以nginx-ingress-controller組件為例說明如何將集群已安裝的組件導入Terraform管理。

1. 新建一個后綴名為.tf的文件或使用您已創建的.tf文件，并定義一個Resource。

   Resource中的alicloud_cs_kubernetes_addon用于管理集群的Addon，其中不需要填寫任何內容。

   resource "alicloud_cs_kubernetes_addon" "nginx-ingress-controller" {
   }

2. 執行以下命令，導入集群已安裝的nginx-ingress-controller組件。

   Terraform會拉取集群內的nginx-ingress-controller組件配置，并寫入到后綴名為.state的文件中。

   terraform import alicloud_cs_kubernetes_addon.nginx-ingress-controller <cluster_id>:nginx-ingress-controller

3. 執行命令terraform plan，根據其得到的結果，您可以看到集群內nginx-ingress-controller組件配置和定義的Resource之間的差異。

   根據差異的結果，以及.state后綴的文件內容，補充您在步驟1中寫入的Resource信息。直到執行指令terraform plan，顯示本地的配置與集群中的組件配置沒有任何差異后，即完成了組件的導入。

   resource "alicloud_cs_kubernetes_addon" "nginx-ingress-controller" {
     cluster_id = "XXXXX"
     name = "nginx-ingress-controller"
     version = "v1.2.1-aliyun.1"
     config = jsonencode(
       {
         IngressSlbNetworkType = "internet"
         IngressSlbSpec        = "slb.s2.small"
       }
     )
   }

安裝集群組件

您可以通過Resource中的alicloud_cs_kubernetes_addon在已有集群中安裝組件，下面以gatekeeper組件為例說明。

1. 在.tf文件中定義待安裝組件的信息，需要指定以下信息。

   • 集群ID。

   • 組件名稱和組件版本：

     集群可安裝的組件名稱和組件版本可以通過Data Source中的alicloud_cs_kubernetes_addons查詢，查詢結果僅返回每個組件最新的可安裝版本。如果您需要安裝組件的歷史版本，請查看對應組件的Release日志，并指定對應的組件版本號。

   • （可選）組件的自定義配置：

     修改config字段進行組件自定義配置，可以使用Terraform內置的jsonencode方法來構建您需要的配置。組件的可配置參數可以通過Data Source中的alicloud_cs_kubernetes_addon_metadata進行查詢，具體操作，請參見修改集群組件的自定義配置參數。

   展開查看詳細信息

   resource "alicloud_cs_kubernetes_addon" "gatekeeper" {
     cluster_id = "ce36b7c61e126430b8b245730ca6d****"
     name = "gatekeeper"
     version = "v3.8.1.113-geb7947ef-aliyun"
     config = jsonencode(
       {
         AdmissionPodCpuLimit      = "1000m"
         AdmissionPodCpuRequest    = "100m"
         AdmissionPodMemoryLimit   = "512Mi"
         AdmissionPodMemoryRequest = "256Mi"
         AdmissionPodNumber        = 3
         AuditInterval             = 1800
         AuditPodCpuLimit          = "1000m"
         AuditPodCpuRequest        = "100m"
         AuditPodMemoryLimit       = "512Mi"
         AuditPodMemoryRequest     = "256Mi"
         EnableAuditPod            = false
         EnableMutatingWebhook     = false
       }
     )
   }

2. 執行以下命令，在集群中安裝組件。

   terraform apply

   預期輸出：

   Plan: 1 to add, 0 to change, 0 to destroy.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   alicloud_cs_kubernetes_addon.gatekeeper: Creating...
   alicloud_cs_kubernetes_addon.gatekeeper: Still creating... [10s elapsed]
   alicloud_cs_kubernetes_addon.gatekeeper: Creation complete after 16s [id=XXXXX:gatekeeper]
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

   直到顯示Apply complete!，說明組件安裝完成。

升級集群組件

您可以通過Data Source中的alicloud_cs_kubernetes_addons來查詢組件可升級的版本，如果發現有新版本的組件可升級，可以通過直接修改版本號的方式進行升級，下面以gatekeeper組件為例說明。

resource "alicloud_cs_kubernetes_addon" "gatekeeper" {
  cluster_id = "ce36b7c61e126430b8b245730ca6d****"
  name = "gatekeeper"

  # 修改Version為指定的可升級版本。
  version = "XXXXXXXXX"
  config = jsonencode(
    {
      AdmissionPodCpuLimit      = "1000m"
      AdmissionPodCpuRequest    = "100m"
      AdmissionPodMemoryLimit   = "512Mi"
      AdmissionPodMemoryRequest = "256Mi"
      AdmissionPodNumber        = 3
      AuditInterval             = 1800
      AuditPodCpuLimit          = "1000m"
      AuditPodCpuRequest        = "100m"
      AuditPodMemoryLimit       = "512Mi"
      AuditPodMemoryRequest     = "256Mi"
      EnableAuditPod            = false
      EnableMutatingWebhook     = false
    }
  )
}

執行命令terraform apply，進行組件升級，顯示成功即完成了組件的升級。

修改集群組件的自定義配置參數

ACK的某些組件開啟了用戶自定義參數的配置能力，您可以通過Resource中的alicloud_cs_kubernetes_addons修改更新您的組件配置，以gatekeeper組件為例，您可以通過修改config字段來修改組件配置。

resource "alicloud_cs_kubernetes_addon" "gatekeeper" {
  cluster_id = "ce36b7c61e126430b8b245730ca6d****"
  name = "gatekeeper"
  version = "v3.8.1.113-geb7947ef-aliyun"

  # 您可以修改Config中的屬性并應用，來修改集群組件配置。

}

如果您需要查看組件支持的全部可配置參數，可以通過Data Source中的alicloud_cs_kubernetes_addon_metadata進行查詢，查詢結果的返回值為JSON Schema格式，以gatekeeper組件為例，您可以將以下內容添加到.tf文件中。

# 定義Data Source獲取gatekeeper組件的可配置參數Schema。
data "alicloud_cs_kubernetes_addon_metadata" "default" {
  cluster_id = "ce36b7c61e126430b8b245730ca6d****"
  name       = "gatekeeper"
  version    = "v3.8.1.113-geb7947ef-aliyun"
}

# 通過Output進行輸出。
output "addon_config_schema" {
  value = data.alicloud_cs_kubernetes_addons.default.config_schema
}

addon_config_schema = <<EOT
{
  "$schema": "http://json-schema.org/draft-07/schema#",
  "properties": {
    "AdmissionPodCpuLimit": {
      "default": "1000m",
      "description": "cpu limit for gatekeeper",
      "pattern": "^(|[1-9][0-9]*(m|\\.\\d+)?)$",
      "type": "string"
    },
    "AdmissionPodCpuRequest": {
      "default": "100m",
      "description": "cpu request for gatekeeper",
      "pattern": "^[1-9][0-9]*(m|\\.\\d+)?$",
      "type": "string"
    },
    "AdmissionPodMemoryLimit": {
      "default": "512Mi",
      "description": "memory limit for gatekeeper",
      "pattern": "^(|[1-9][0-9]*(\\.\\d+)?(K|Ki|M|Mi|G|Gi|T|Ti)?)$",
      "type": "string"
    },

    ......
  },
  "title": "Config",
  "type": "object"
}
EOT

配置網絡組件

在ACK中，您可以通過Terway網絡模式實現上述容器網絡的能力。更多信息，請參見網絡概述。

# 使用Terway作為網絡組件，并且使用Pod獨占彈性網卡模式，默認此方式。
# 該模式下，節點Pod數量將受到ECS彈性網卡配額限制。

resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "terway-eni"
  }
}

# 使用Terway作為網絡組件，并且使用IPVlan模式。
# 采用IPVlan + ebpf作為網卡共享模式虛擬化技術，只能使用Alibaba Cloud Linux 2系統。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   =  "terway-eniip",
    config = "{\"IPVlan\":\"true\",\"NetworkPolicy\":\"false\"}"
  }
}

# 使用Terway作為網絡組件，并且IPVlan模式下啟用NetworkPolicy策略支持。
# 采用IPVlan + ebpf作為網卡共享模式虛擬化技術，只能使用Alibaba Cloud Linux 2系統。
# IPVlan模式下，提供了基于策略的網絡控制。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   =  "terway-eniip",
    config = "{\"IPVlan\":\"true\",\"NetworkPolicy\":\"true\"}"
  }
}

配置存儲組件

# 使用CSI作為存儲組件時，CSI包含csi-plugin、csi-provisioner；如果還想啟用創建默認的NAS文件系統和CNFS容器網絡文件系統動態存儲類型，還需要安裝storage-operator組件。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "csi-plugin"
  }
  addons {
    name = "csi-provisioner"
  }
  addons {
    name   = "storage-operator"
    config = "{\"CnfsOssEnable\":\"false\",\"CnfsNasEnable\":\"true\"}"
  }
}

配置日志組件

# 使用自動創建SLS Project作為日志存儲。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "logtail-ds"
  }
}

# 使用自動創建SLS Project做日志存儲。同時開啟自動創建Ingress看板。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "logtail-ds"
    config = "{\"IngressDashboardEnabled\":\"true\"}
  }
}


# 使用已有SLS Project做日志存儲。同時開啟自動創建Ingress看板。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "logtail-ds"
    config = "{\"IngressDashboardEnabled\":\"true\",\"sls_project_name\":\"k8s-log-c55c35ff493df47b88783bea48827****\"}"
  }
}

# 安裝配置node-problem-detector事件中心。
# 使用自動創建SLS Project作為事件中心的日志存儲。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   = "ack-node-problem-detector"
    config = "{\"sls_project_name\":\"\"}"
  }
}

# 安裝配置node-problem-detector事件中心。
# 使用已有SLS Project作為事件中心的日志存儲。可以和logtail-ds共用同一個日志庫。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   = "ack-node-problem-detector"
    config = "{\"sls_project_name\":\"k8s-log-c55c35ff493df47b88783bea48827****\"}"
  }
}

配置監控組件

# 安裝ECS節點上安裝的云監控插件。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...
  install_cloud_monitor = true
}

# 安裝Prometheus監控。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name = "arms-prometheus"
  }
}

# 同時安裝ECS節點上安裝的云監控插件和Prometheus監控服務。

# 安裝Prometheus監控, 推薦同時啟用。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...
  install_cloud_monitor = true
  addons {
    name = "arms-prometheus"
  }
}

配置Ingess路由組件

# 使用nginx-ingress-controller路由。
# 如果使用公網的SLB，需要在Config中設置IngressSlbNetworkType值為internet。
# 如果使用私網的SLB，需要在Config中設置IngressSlbNetworkType值為intranet。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   =  "nginx-ingress-controller",
    config = "{\"IngressSlbNetworkType\":\"internet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
  }
}

# 使用ALB Ingress路由。
resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name   = "alb-ingress-controller",
  }
}

禁用默認安裝的組件

# 禁止安裝nginx-ingress-controller組件。

resource "alicloud_cs_managed_kubernetes" "default" {
  # 其它參數。
  # ...

  addons {
    name     =  "nginx-ingress-controller",
    disabled = true
  }
}

未指定Addons的情況下默認安裝的組件

如果集群創建時，沒有指定任何Addons，會默認安裝以下組件。

常用配置示例

# 集群創建不配置任何組件，則僅安裝默認組件。
# 一個集群的最簡配置，變量請替換為您自定義的變量。
resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = var.name
  cluster_spec                 = "ack.pro.small"
  is_enterprise_security_group = true
  pod_cidr                     = "172.20.0.0/16"
  service_cidr                 = "172.21.0.0/20"
  worker_vswitch_ids           = ["var.vswitch_id"]
}

# 創建Terway網絡集群。
# 使用Pod獨占彈性網卡模式。

resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = var.name
  cluster_spec                 = "ack.pro.small"
  is_enterprise_security_group = true
  pod_vswitch_ids              = [var.vswitch_id]
  service_cidr                 = "172.21.0.0/20"
  worker_vswitch_ids           = ["var.vswitch_id"]

  addons {
    name = "terway-eni"
  }
}

# 創建Terway網絡集群。
# 同時使用IPVlan模式，并且開啟網絡策略。
resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = var.name
  cluster_spec                 = "ack.pro.small"
  is_enterprise_security_group = true
  service_cidr                 = "172.21.0.0/20"
  pod_vswitch_ids              = ["var.vswitch_id"]
  worker_vswitch_ids           = ["var.vswitch_id"]

  addons {
    name   =  "terway-eniip"
    config = "{\"IPVlan\":\"true\",\"NetworkPolicy\":\"true\"}"
  }
}

# Terway + CSI + nginx-ingress通用模板。

resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = var.name
  cluster_spec                 = "ack.pro.small"
  is_enterprise_security_group = true
  service_cidr                 = "172.21.0.0/20"
  pod_vswitch_ids              = ["var.vswitch_id"]
  worker_vswitch_ids           = ["var.vswitch_id"]

  addons {
    name = "terway-eniip",
    config = "{\"IPVlan\":\"true\",\"NetworkPolicy\":\"false\"}"
  }
  addons {
    name = "csi-plugin"
  }
  addons {
    name = "csi-provisioner"
  }
  addons {
    name = "storage-operator"
    config = "{\"CnfsOssEnable\":\"false\",\"CnfsNasEnable\":\"true\"}"
  }
  addons {
    name = "logtail-ds"
    config = "{\"IngressDashboardEnabled\":\"true\"}"
  }
  addons {
    name = "ack-node-problem-detector"
    config = "{\"sls_project_name\":\"\"}"
  }
  addons {
    name = "nginx-ingress-controller"
    config = "{\"IngressSlbNetworkType\":\"internet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
  }
  addons {
    name = "ack-node-local-dns"
  }
  addons {
    name = "arms-prometheus"
  }
  addons {
    name = "alicloud-monitor-controller"
    config = "{\"group_contact_ids\":\"[10619]\"}"
  }
}